<%
' MyPAYE
' Module: GenericAEExportFormat.asp
'
' This software is the copyright of Mr T J Sheppard and may not be copied, duplicated or 
' modified other than as permitted in the licence agreement.
'
'       Š 2012 - 2021  Mr T J Sheppard
'                      Lyndale House
'                      Church Street
'                      Bradwell
'                      Hope Valley
'                      S33 9HJ
'
'  Tel 0845 643 5191
'  Email Support@MyPAYE.co.uk
'
' MyPAYE is a Registered Trademark of MyPAYE Ltd
'-------------------------------------------------------------------
'
' Updated 09 April 2021
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
'   Description -    This module enables a user defined Generic AE export file format.
'
' Amendment Log
'------------------------------------------------------------------------------------------
' Date     | Name            | Vers.  | Description
'------------------------------------------------------------------------------------------
' 21/03/16 | DC              | 5.0.05 | Page added
' 17/06/15 | DC              | 5.0.08 | Added Gross earnings
' 08/12/15 | DC              | 5.0.17 | Added Taxable earnings
' 21/02/17 | DC              | 5.0.17a| Added Non-Banded pens earnings, and added code to clear
'          |                 |        | text when checkbox cleared.
'          |                 |        | Fixed non-working LogOut.
' 10/10/17 | TJS             | 5.1.10 | Corrected conflict where PSID param was used for both PaySlipID and PenSchID on new employee wizard
' 20/10/19 | TJS             | 5.7.00 | Modified to use GetMainMenuParam to save having to read lots of parameters for each page build
' 25/02/20 | TJS             | 5.7.04 | Modified to cater for Partner only reports on Multi Employer Overview
' 30/05/20 | TJS             | 5.8.00 | Modified for new styling - added centered class on body and modified to replace stylesheet.css, mainmenu.css and buttons-css.asp with BodyAndMenu-css.asp
' 09/04/21 | TJS             | 5.9.09 | Modified to use ASPDOTNET/LogOut.aspx and ASPDOTNET/AgencyCancel.aspx pages
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
 
PageID = 43183
NoBack = True
if Request.ServerVariables("request_method") = "GET" then
	SessionID = request.querystring("ID")
	SessionVarsID = RemoveHTML(request.querystring("SV")) 
	SourceFrame = RemoveHTML(request.querystring("S"))
	DestFrame = RemoveHTML(request.querystring("D"))
	EmployerID = CheckURLDBIDField(RemoveHTML(request.querystring("ER")), "EmployerID")
	AddNewEdit = RemoveHTML(request.querystring("ANE"))
	CancelPage = RemoveHTML(request.querystring("CPge"))
else
	SessionID = request.form("ID")
	SessionVarsID = RemoveHTML(request.form("SV")) 
	SourceFrame = RemoveHTML(request.form("S"))
	DestFrame = RemoveHTML(request.form("D"))
	EmployerID = CheckURLDBIDField(RemoveHTML(request.form("ER")), "EmployerID")
	AddNewEdit = RemoveHTML(request.form("ANE"))
	CancelPage = RemoveHTML(request.form("CPge"))
end if
%>

<!--#include file ="Functions\CoreValidationRoutines.asp"-->

<!--#include file ="Functions\ConnectDatabaseMain.asp"-->

<!--#include file ="Functions\CreateSessionID.asp"-->

<!--#include file ="Functions\FrameNameConst.asp"-->

<%GetSessionVarsIDRecord(SessionVarsID)%>

<!--#include file ="Functions\DataProtection.asp"-->

<!--#include file ="Functions\URLValidation.asp"-->

<%
if Request.ServerVariables("request_method") = "GET" then
	FailureFields = RemoveHTML(request.querystring("FFld"))
	FailureMessage = RemoveHTML(request.querystring("FMsg"))
	AlertMessage = RemoveHTML(request.querystring("AlMsg"))
else
	FailureFields = RemoveHTML(request.form("FFld"))
	FailureMessage = RemoveHTML(request.form("FMsg"))
	AlertMessage = RemoveHTML(request.form("AlMsg"))
end if

Function CheckValidationFailure(FieldName)
	if instr(1, FailureFields, ":" & FieldName & ":") = 0 then
		' no failure - set control to normal
		CheckValidationFailure = "" 
	else
		' validation failed - set control to red outline
		CheckValidationFailure = "-error"
	end if
end Function

' get details for user who is logged in 
sql = "SELECT Employer_ID, " & UserTableMenuPermissionFields & " FROM " & DBSchema & "Users INNER JOIN " & DBSchema & "User_Permissions " 
sql = sql & "ON Users.User_ID = User_Permissions.User_ID AND (Employee_Employer_ID = '' OR Employee_Employer_ID = '" 
sql = sql & EncodeEmployerID(UserPermissionsTable, EmployerID) & "') WHERE Users.User_ID = " & GetSessionVar("UserID") 
sql = sql & " AND User_Permissions.Deleted = 0 ORDER BY Employee_Employer_ID DESC" 
set rsUser = OpenRecordset(objConn, sql)

sql = "SELECT " & EmployerTableMenuOptionFields & " FROM " & DBSchema & "Employers WHERE Employer_ID = " & EmployerID
set rsEmployer = OpenRecordset(objConn, sql)

ReadMainMenuParams SessionVarsID, cBool(rsUser("User_Admin")), (cBool(rsUser("Run_Payroll")) or cBool(rsUser("Payroll_EOY")) or cBool(rsUser("CIS_Returns"))), _
	cBool(rsUser("Run_Payroll")), rsUser("Support_User_ID") ' TJS 20/10/19

if AddNewEdit <> "Edit" then
	ReadOnly=" readonly"
	AllowChanges = false 
else
	ReadOnly=""
	AllowChanges = true
end if

response.Expires = -1500
response.Expiresabsolute = Now() - 2
response.AddHeader "pragma", "no-cache"
response.AddHeader "cache-control", "no-store"
response.CacheControl = "no-cache"
%>
<!DOCTYPE html>
<html>

<head>
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">
<title>Generic AE Export File Format</title>

<!-- START OF STYLES -->
<link rel="stylesheet" type="text/css" href="css/BodyAndMenu-css.asp" /> <!-- TJS 30/05/20 -->
<link rel="stylesheet" type="text/css" href="css/forms-css.asp" />
<%if CheckBrowserVersion("MSIE", 8, true, false, false) then ' [if LT IE 8]%>
	<link type="text/css" rel="stylesheet" href="css/buttons-ie.css" />
<%end if
if CheckBrowserVersion("MSIE", 7, true, true, false) then ' [if lte IE 7]%>
	<style>
		.content { margin-right: -1px; } /* this 1px negative margin can be placed on any of the columns in this layout with the same corrective effect. */
		ul.nav a { zoom: 1; }  /* the zoom property gives IE the hasLayout trigger it needs to correct extra whiltespace between the links */
	</style>
<%end if
if "" & GetSessionVar("PathModifier") <> "" then%>
	<link rel="stylesheet" type="text/css" href="css/<%=GetSessionVar("PathModifier")%>Partner-CSS.asp" />
<%end if%>
<!-- END OF STYLES -->

<script src="JavaScript/KeepAliveJS.asp?SV=<%=SessionVarsID%>">
</script>

<link rel="meta" href="http://www.mypaye.co.uk/labels.xml" type="application/rdf+xml" title="ICRA labels" />
<meta http-equiv="pics-Label" content='(pics-1.1 "http://www.icra.org/pics/vocabularyv03/" l gen true for "http://mypaye.co.uk" r (n 0 s 0 v 0 l 0 oa 0 ob 0 oc 0 od 0 oe 0 of 0 og 0 oh 0 c 0) gen true for "http://www.mypaye.co.uk" r (n 0 s 0 v 0 l 0 oa 0 ob 0 oc 0 od 0 oe 0 of 0 og 0 oh 0 c 0))' />

<script>
var buttonsdisabled = false; // 21/02/17

function checkkeypress(evt)
{
	var e =(window.event) ? window.event : evt;

	if (((((e.keyCode >= 48) && (e.keyCode <= 111) && (e.keyCode != 91) && (e.keyCode != 93)) || (e.keyCode == 8) || (e.keyCode == 32) 
		|| (e.keyCode == 46) || ((e.keyCode >= 186) && (e.keyCode <= 192)) || ((e.keyCode >= 219) && (e.keyCode <= 223))) && (!e.ctrlKey)) 
		|| ((e.ctrlKey) && ((e.keyCode == 86) ||(e.keyCode == 88)))) 
	{
		datachanged();
		return true;
	}
	else
	{
		return false;
	}
}

function undoselect(ctrl, origvalue)
{
	ctrl.value = origvalue
}

function closewindow()
{
	cls=document.getElementById('Close');
	ane=document.getElementById('ANE');
	if (cls.innerHTML == 'Cancel') 
	{
		window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/GenericAEExportFormat.asp?ID=<%=SetPageSessionID(43183, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=DestFrame%>&ER=<%=EmployerID%>&ANE=' + ane.value + '&CPge=<%=CancelPage%>','_self','',true);
	}
	else
	{
		window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/EmployerOptions.asp?ID=<%=SetPageSessionID(51668, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=DestFrame%>&ER=<%=EmployerID%>&ANE=' + ane.value + '&CPge=<%=CancelPage%>','_self','',true);
	}
}

function updatesubmit()
{
	cls=document.getElementById('Close');
	if (cls.innerHTML == 'Cancel') 
	{
		upd=document.getElementById('Update');
		if ((upd.className != 'continue_button_disabled')) 
		{
	 		document.AEFmtForm.submit();
		}
	}	
}

function datachanged()
{
	cls=document.getElementById('Close');
	upd=document.getElementById('Update');
	if ((cls.innerHTML == 'Close') || (upd.className == 'continue_button_disabled')) 
	{
		cls.innerHTML = 'Cancel'; 
		upd.className='continue_button'; 
	}
}

function OpenTabERForm(ctrl, destination, id)
{ 
	// Pension Scheme ID (PenSchID) set for all windows even though only Pension Scheme needs it
	window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/' + destination + '?ID=' + id + '&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=DestFrame%>&ER=<%=EmployerID%>&PenSchID=-1&ANE=Edit&CPge=PayrollHome.asp', '_self','',true);
}

function GoPayrollHome() 
{
	window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/PayrollHome.asp?ID=<%=SetPageSessionID(38684, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=MainFrame%>&PR=-1&ER=<%=EmployerID%>&RPy=No&RrP=No&CNP=No','PayrollHome','',true);
}

function LogOut() 
{
	if (!buttonsdisabled)
 	{
		buttonsdisabled = true;
		<%if GetSessionVar("AgencyID") = "" or GetSessionVar("AgencyID") = -1 then
			CancelPath = "/Secure/ASPDOTNET/LogOut.aspx" ' TJS 09/04/21
		else
			CancelPath = "/Secure/ASPDOTNET/AgencyCancel.aspx" ' TJS 09/04/21
		end if%>
		window.open('https://<%=request.servervariables("SERVER_NAME") & CancelPath%>?ID=<%=SetPageSessionID(10022, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=MainFrame%>&ER=<%=EmployerID%>','PayrollHome','', true);
	}
}

function OpenSupportCentre()
{
	window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/Support/UserSupport.asp?ID=<%=SetPageSessionID(96334, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=MainFrame%>&ER=<%=EmployerID%>&WthMnu=Yes','PayrollHome','', true);
}

function SetText(i,txt) 
{
	cn = document.getElementById('CustName' + i);
	cb = document.getElementById('Include' + i); // DC 21/02/17
	srt = document.getElementById('Sort' + i); // DC 21/02/17

	if (cb.checked)
	{
		if(cn.value == '')
		{
			cn.value = txt
		}
	}
	else // DC 21/02/17
	{
		cn.value = '' // DC 21/02/17
		srt.value = '0' // DC 21/02/17
	}
	datachanged()
}

</script>

<!--#include file ="Functions\GoogleAnalytics.asp"-->

</head>

<body class="centered"> <!-- TJS 30/05/20 -->

<!--#include file ="PayrollHeader.asp"-->

<%MenuShowHome = true
MenuShowEmployer = true
MenuShowFindEmployee = true
MenuShowUsers = true
MenuShowCreate = true
MenuShowCreatePayroll = true
MenuShowCreateEmployer = true
MenuShowCreateUser = true
MenuShowHMRC = true
MenuShowReports = true
MenuPartnerReportsOnly = false ' TJS 25/02/20
MenuShowPayrollData = true
MenuShowTools = true
MenuShowSupport = true
MenuSelected = ""
MenuEmployerExists = true
MenuShowAccount = true%>

<!--#include file ="MainMenu.asp"-->

<script>
	//set location in header
	document.getElementById("ProgramLocation").innerHTML = "<h1>Generic AE Export File Format</h1>";
	setTimeout("KeepAlive('<%=SessionVarsID%>')", 60000);
</script>

	<%dim arBaseNames(32) ' DC 17/06/16 DC 08/12/16 21/02/17
		arBaseNames(1) = "Title"
		arBaseNames(2) = "Employee First Name"
		arBaseNames(3) = "Employee Surname"
		arBaseNames(4) = "Date Of Birth"
		arBaseNames(5) = "National Insurance Number"
		arBaseNames(6) = "Gender"
		arBaseNames(7) = "Payroll Ref"
		arBaseNames(8) = "Address 1"
		arBaseNames(9) = "Address 2"
		arBaseNames(10) = "Town/City"
		arBaseNames(11) = "County"
		arBaseNames(12) = "Post Code"
		arBaseNames(13) = "Country"
		arBaseNames(14) = "E-mail Address"
		arBaseNames(15) = "Employee Start Date"
		arBaseNames(16) = "Leaving Date"
		arBaseNames(17) = "Pay Period"
		arBaseNames(18) = "Pay Frequency"
		arBaseNames(19) = "Enrolment Date"
		arBaseNames(20) = "Postponement Date"
		arBaseNames(21) = "Opt Out Date"
		arBaseNames(22) = "AE Status"
		arBaseNames(23) = "Pensionable Earnings"
		arBaseNames(24) = "Employee Cont Ł"
		arBaseNames(25) = "Employee Cont %"
		arBaseNames(26) = "Employer Cont Ł"
		arBaseNames(27) = "Employer Cont %"
		arBaseNames(28) = "AVC Cont Ł"
		arBaseNames(29) = "AVC Cont %"
		arBaseNames(30) = "Gross Earnings" ' DC 17/05/16
		arBaseNames(31) = "Taxable Earnings" ' DC 08/12/16
		arBaseNames(32) = "NonBanded Pensionable Earnings" ' DC 21/02/17
				
		sql = "SELECT Source_Col_ID, Custom_Name, Sort_Order FROM " & DBSchema & "Gen_AE_File_Format WHERE Employer_ID = " & EmployerID
		sql = sql & " AND Source_Col_ID > 0 AND Deleted = 0 ORDER BY Source_Col_ID"
		set rsFileFmt = OpenRecordset(objConn, sql)	
		
		sql = "SELECT Source_Col_ID, Custom_Name, Sort_Order FROM " & DBSchema & "Gen_AE_File_Format WHERE Employer_ID = " & EmployerID
		sql = sql & " AND Source_Col_ID < 0 AND Deleted = 0 ORDER BY Source_Col_ID"
		set rsFillerFields = OpenRecordset(objConn, sql)	

		%>

<form method="post" name="AEFmtForm" action="https://<%=request.servervariables("SERVER_NAME")%>/Secure/UpdateGenAEFileFormat.asp">
	<input type="hidden" name="ID" value="<%=SetPageSessionID(68344, DestFrame)%>">
	<input type="hidden" name="SV" value="<%=SessionVarsID%>">
	<input type="hidden" name="S" value="<%=DestFrame%>">
	<input type="hidden" name="D" value="<%=DestFrame%>">
	<input type="hidden" name="ER" value="<%=EmployerID%>">
	<input type="hidden" name="ANE" id="ANE" value="<%=AddNewEdit%>">
	<input type="hidden" name="CPge" value="<%=CancelPage%>">
	
	<%if "" & FailureMessage <> "" then%>
		<p style="text-align: left; padding: 0px 5px;"><%=FailureMessage%><input type="hidden" name="FFld" value="<%=FailureFields%>"></p>
	<%end if%>
			
	<fieldset class="FormPanelCentered" style="width: 600px;">
		<div id="ScrollArea" style="border : 0px solid #ffff00; height : 500px; width : 650px; overflow : auto; margin:auto;">			
			<table class="FormPanel" style="width:590px;">
				<tr>
					<td colspan="4"><p class="panelhdr">Names and column positions for Generic Auto Enrolment Export File.</p></td>
				</tr>
				<tr>
					<td colspan="4">&nbsp;</td>
				</tr>
				<tr>
					<td class="payroll-list-hdr" style="width:280px;"><b>Generic Name</b></td>
					<td class="payroll-list-hdr" style="width:120px; text-align:center;"><b>Include</b></td>
					<td class="payroll-list-hdr" style="width:300px;">Custom Name</td>
					<td class="payroll-list-hdr" style="width:120px;"><b>Col. Posn.</b></td>
				</tr>
								
				<%For iLoop = 1 to UBound(arBaseNames)%>
					<tr>					
						<td style="width:280px;"><%=arBaseNames(iLoop)%></td>

						<%if "" & FailureFields = "" then
							' Build list from dataset	
							do while not rsFileFmt.EOF	
								if cInt(rsFileFmt("Source_Col_ID")) = iLoop then
									CustName = rsFileFmt("Custom_Name")
									iSort = cInt(rsFileFmt("Sort_Order"))
									bChecked = True
									exit do
								else
									CustName = ""
									iSort = 0
									bChecked = False
								end if
								rsFileFmt.movenext
							Loop
							if not rsFileFmt.BOF then 
								rsFileFmt.movefirst
							end if							
						else
							' Build list from form
							CustName = RemoveHTML(request.form("CuNme" & iLoop))
							iSort = cInt(RemoveHTML(request.form("Srt" & iLoop)))
							if RemoveHTML(request.form("Incl" & iLoop)) = "ON" then
								bChecked = True
							else
								bChecked = False
							end if				
						end if%>				
													
						<td style="width:120px; text-align:center;"><input type="checkbox" name="Include<%=iLoop%>" id="Include<%=iLoop%>" <%if bChecked then response.write "checked" end if%> value="ON" onclick="SetText(<%=iLoop%>, '<%=arBaseNames(iLoop)%>')"></td>															
						<td style="width:300px;"><input name="CustName<%=iLoop%>" id="CustName<%=iLoop%>" type="text" class="full-input<%=CheckValidationFailure("CustName" & iLoop)%><%if AllowChanges then%><%else%>-readonly<%end if%>"  maxlength="48" value="<%=CustName%>" <%=ReadOnly%><%if AllowChanges then%> onkeydown="checkkeypress(event)"<%end if%>></td>
						<td style="width:120px;"><select name="Sort<%=iLoop%>" id="Sort<%=iLoop%>" class="select-full-input<%=CheckValidationFailure("Sort" & iLoop)%><%if AllowChanges then%><%else%>-readonly<%end if%>" onchange="<%if AllowChanges then%>datachanged()<%else%>undoselect(this, '<%=iSort%>')<%end if%>" <%=ReadOnly%>>
							<option value="0">&nbsp;</option>
							<%For iLoop2 = 1 to UBound(arBaseNames)%>						
								<option value="<%=iLoop2%>"<%if iLoop2 = iSort then%> selected<%end if%>><%=iLoop2%></option>
							<%next%>
							</select>
						</td>
					</tr>
				<%next%>
				
				<!-- Additional 'Filler' rows to go in here -->
				
				
			</table>
		</div>
	</fieldset>
	<p style="clear: left; padding: 10px;"><a id="Update" class="continue_button_disabled" onclick="updatesubmit()">Update</a>
	<a id="Close" class="cancel_button" onclick="closewindow()">Close</a></p>
</form>

<%if "" & AlertMessage <> ""then%>
	<script>
		window.alert("<%=replace(AlertMessage, "\&#x27;", "\'")%>"); 
	</script>
<%end if%>

</body>
</html>
<%
ReleaseASPEncrypt

rsFileFmt.close
rsUser.close
rsEmployer.close
set rsFileFmt = nothing
set rsUser = nothing
set rsEmployer = nothing

SaveSessionVarsRecord SessionVarsID 

objConn.close
set objConn = nothing
%>