<%
' MyPAYE
' Module: SelectTransferCredit.asp
'
' This software is the copyright of Mr T J Sheppard and may not be copied, duplicated or 
' modified other than as permitted in the licence agreement.
'
'       © 2012 - 2021  Mr T J Sheppard
'                      Lyndale House
'                      Church Street
'                      Bradwell
'                      Hope Valley
'                      S33 9HJ
'
'  Tel 0845 643 5191
'  Email Support@MyPAYE.co.uk
'
' MyPAYE is a Registered Trademark of MyPAYE Ltd
'-------------------------------------------------------------------
'
' Updated 24 September 2021

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
'   Description -    This module 
'
' Amendment Log
'------------------------------------------------------------------------------------------
' Date     | Name            | Vers.  | Description
'------------------------------------------------------------------------------------------
' 17/07/07 | TJS             | 1.2.03 | Page added
' 18/11/10 | TJS             | 1.5.00 | Modified to use both root and agency CSS files when used to 
'                                     | eliminate duplicated settings in agency CSS files
' 22/12/10 | TJS             | 1.5.01a | Modified to cater for Login_Disabled in Multi_Company_Logins
' 08/08/12 | TJS             | 2.0.05 | Google Analytics added
' 01/06/14 | DC              | 4.0.00 | Modified for new styling and operation without framesets
' 07/06/14 | TJS             | 4.0.00 | Corrected centering of tables
' 05/10/14 | TJS             | 4.0.04 | Modified for Encrypted Employer ID check
' 30/10/14 | TJS             | 4.0.05 | Modified display of Alert Messages to cater for RemoveHTML changes
' 26/11/15 | TJS             | 5.0.00 | Modified to cater for separate User_Permissions table
' 20/10/19 | TJS             | 5.7.00 | Modified to use GetMainMenuParam to save having to read lots of parameters for each page build
' 30/05/20 | TJS             | 5.8.00 | Modified for new styling - added centered class on body and modified to replace stylesheet.css, mainmenu.css and buttons-css.asp with BodyAndMenu-css.asp
' 25/09/20 | TJS             | 5.9.00 | Modified to prevent double clicking on change employer listbox
' 24/09/21 | TJS             | 5.9.12 | Modified to replace alert and confirm dialogues to cater for browser blocks on cross site dialogs and to use ASPDOTNET/ViewAccountHistory.aspx page
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
 
PageID = 22486
SessionID = request.querystring("ID")
SessionVarsID = RemoveHTML(request.querystring("SV"))
SourceFrame = RemoveHTML(request.querystring("S"))
DestFrame = RemoveHTML(request.querystring("D"))
EmployerID = CheckURLDBIDField(RemoveHTML(request.querystring("ER")), "EmployerID")
%>

<!--#include file ="Functions\CoreValidationRoutines.asp"-->

<!--#include file ="Functions\ConnectDatabaseMain.asp"-->

<!--#include file ="Functions\CreateSessionID.asp"-->

<!--#include file ="Functions\FrameNameConst.asp"-->

<%GetSessionVarsIDRecord(SessionVarsID)%>

<!--#include file ="Functions\DataProtection.asp"-->

<!--#include file ="Functions\URLValidation.asp"-->

<%Function CheckValidationFailure(FieldName)

	if instr(1, FailureFields, ":" & FieldName & ":") = 0 then
		' no failure - set control to normal
		CheckValidationFailure = "" ' TJS 01/06/14
	else
		' validation failed - set control to red outline
		CheckValidationFailure = "-error" ' TJS 01/06/14
	end if
	
end Function

FailureFields = RemoveHTML(request.querystring("FFld"))
FailureMessage = RemoveHTML(request.querystring("FMsg"))
AlertMessage = RemoveHTML(request.querystring("AlMsg"))
TransferToEmployerID = CheckURLDBIDField(RemoveHTML(request.querystring("TrnsER")), "TransferToEmployerID")
EmplMntsToTransfer = ValidateIntegerValue(RemoveHTML(Trim(request.querystring("EMTransfer"))), "EMTransfer")

sql = "SELECT " & UserTableMenuPermissionFields & ", Sort_Employer_List FROM " & DBSchema & "Users INNER JOIN " & DBSchema ' TJS 26/11/15
sql = sql & "User_Permissions ON Users.User_ID = User_Permissions.User_ID AND (Employee_Employer_ID = '' OR Employee_Employer_ID = '" ' TJS 26/11/15
sql = sql & EncodeEmployerID(UserPermissionsTable, EmployerID) & "') WHERE Users.User_ID = " & GetSessionVar("UserID") ' TJS 26/11/15
sql = sql & " AND User_Permissions.Deleted = 0 ORDER BY Employee_Employer_ID DESC" ' TJS 26/11/15
set rsUser = OpenRecordset(objConn, sql)

sql = "SELECT " & EmployerTableMenuOptionFields & ", Billing_Method, Empl_Mnths_Credit FROM " & DBSchema & "Employers WHERE Employer_ID = " & EmployerID
set rsEmployer = OpenRecordset(objConn, sql)

ReadMainMenuParams SessionVarsID, cBool(rsUser("User_Admin")), (cBool(rsUser("Run_Payroll")) or cBool(rsUser("Payroll_EOY")) or cBool(rsUser("CIS_Returns"))), _
	cBool(rsUser("Run_Payroll")), rsUser("Support_User_ID") ' TJS 20/10/19

if "" & EmplMntsToTransfer = "" then
	EmplMntsToTransfer = rsEmployer("Empl_Mnths_Credit")
end if

sql = "SELECT Multi_Company_Logins.Employer_ID, Employers.Employer_Name FROM " & DBSchema & "Multi_Company_Logins, "
sql = sql & DBSchema & "Employers WHERE Multi_Company_Logins.Employer_ID = Employers.Employer_ID AND User_ID = '"
sql = sql & EncodeUserID(MultiCompLoginTable, GetSessionVar("UserID")) & "' AND Multi_Company_Logins.Deleted = 0 AND "
sql = sql & "Multi_Company_Logins.Login_Disabled = 0 AND Multi_Company_Logins.Employer_ID <> " & EmployerID ' TJS 22/12/10
if cBool(rsUser("Sort_Employer_List")) then
	sql = sql & " ORDER BY Employer_Name"
end if
set rsTransferTo = OpenRecordset(objConn, sql)

response.Expires = -1500
response.Expiresabsolute = Now() - 2
response.AddHeader "pragma", "no-cache"
response.AddHeader "cache-control", "no-store"
response.CacheControl = "no-cache"
%>
<!DOCTYPE html>
<html>

<head>
<meta http-equiv="Content-Type" content="text/html; charset=windows-1252">

<title>Transfer Credit to another Employer</title>

<!-- START OF STYLES -->
<link rel="stylesheet" type="text/css" href="css/BodyAndMenu-css.asp" /> <!-- TJS 30/05/20 -->
<link rel="stylesheet" type="text/css" href="css/forms-css.asp" />
<%if CheckBrowserVersion("MSIE", 8, true, false, false) then ' [if LT IE 8]%>
	<link type="text/css" rel="stylesheet" href="css/buttons-ie.css" />
<%end if
if CheckBrowserVersion("MSIE", 7, true, true, false) then ' [if lte IE 7]%>
	<style>
		.content { margin-right: -1px; } /* this 1px negative margin can be placed on any of the columns in this layout with the same corrective effect. */
		ul.nav a { zoom: 1; }  /* the zoom property gives IE the hasLayout trigger it needs to correct extra whiltespace between the links */
	</style>
<%end if
if "" & GetSessionVar("PathModifier") <> "" then%>
	<link rel="stylesheet" type="text/css" href="css/<%=GetSessionVar("PathModifier")%>Partner-CSS.asp" />
<%end if%>
<!-- END OF STYLES -->

<script src="JavaScript/KeepAliveJS.asp?SV=<%=SessionVarsID%>">
</script>

<link rel="meta" href="http://www.mypaye.co.uk/labels.xml" type="application/rdf+xml" title="ICRA labels" />
<meta http-equiv="pics-Label" content='(pics-1.1 "http://www.icra.org/pics/vocabularyv03/" l gen true for "http://mypaye.co.uk" r (n 0 s 0 v 0 l 0 oa 0 ob 0 oc 0 od 0 oe 0 of 0 og 0 oh 0 c 0) gen true for "http://www.mypaye.co.uk" r (n 0 s 0 v 0 l 0 oa 0 ob 0 oc 0 od 0 oe 0 of 0 og 0 oh 0 c 0))' />

<script>var buttonsdisabled = false;

// start of code added TJS 24/09/21
function GoPayrollHome() 
{
	if (!buttonsdisabled)
	{
		buttonsdisabled = true;
		window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/PayrollHome.asp?ID=<%=SetPageSessionID(38684, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=MainFrame%>&PR=-1&ER=<%=EmployerID%>&RPy=No&RrP=No&CNP=No','PayrollHome','', true);
	}
}

function LogOut()
{
	if (!buttonsdisabled)
	{
		buttonsdisabled = true;
		<%if GetSessionVar("AgencyID") = "" or GetSessionVar("AgencyID") = -1 then
			CancelPath = "/Secure/ASPDOTNET/LogOut.aspx"
		else
			CancelPath = "/Secure/ASPDOTNET/AgencyCancel.aspx"
		end if%>
		window.open('https://<%=request.servervariables("SERVER_NAME") & CancelPath%>?ID=<%=SetPageSessionID(10022, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=MainFrame%>&ER=<%=EmployerID%>','PayrollHome','', true);
	}
}
function ConfirmClick(){

	ca = document.getElementById('ConfAction');
	switch (ca.value)
	{
		case 'close':
			dm = document.getElementById('DialogMask');
			cd = document.getElementById('ConfirmDiv');
			dm.style.display = 'none';
			cd.style.display = 'none';
			break;
			
		default:
			DisplayAlertMsg('System error', 'Unknown action ' + ca.value, 120, 600);
	}
}

function DisplayAlertMsg(DlgHdr, DlgTxt, DlgHeight, DlgWidth){

	dm = document.getElementById('DialogMask');
	ayn = document.getElementById('AskYesNoDiv');
	cd = document.getElementById('ConfirmDiv');
	ch = document.getElementById('ConfirmHdr')
	ct = document.getElementById('ConfirmTxt');
	ca = document.getElementById('ConfAction');
	ch.innerHTML = DlgHdr;
	ct.innerHTML = DlgTxt;
	cd.style.height = DlgHeight + 'px';
	cd.style.width = DlgWidth + 'px';
	cd.style.left = 600 - (parseInt(DlgWidth) / 2) + 'px';
	ca.value = 'close';
	dm.style.display = 'block';
	ayn.style.display = 'none';
	cd.style.display = 'block';
}
// end of code added TJS 24/09/21
</script> <!-- TJS 25/09/20 -->

<!--#include file ="Functions\GoogleAnalytics.asp"-->

</head>

<body class="centered"> <!-- TJS 30/05/20 -->

<!--#include file ="PayrollHeader.asp"-->

<script>
	//set location in header
	document.getElementById("ProgramLocation").innerHTML = "<h1>Transfer Credit</h1>";
	//set Help ID
	document.getElementById("HdrHlpID").value='';
	setTimeout("KeepAlive('<%=SessionVarsID%>')", 60000);
</script>

<%MenuShowHome = true
MenuShowEmployer = false
MenuShowFindEmployee = false
MenuShowUsers = false
MenuShowCreate = false
MenuShowCreatePayroll = false
MenuShowCreateEmployer = false
MenuShowCreateUser = false
MenuShowHMRC = false
MenuShowReports = false
MenuShowPayrollData = false
MenuShowTools = false
MenuShowSupport = false
MenuSelected = ""
MenuEmployerExists = true
MenuShowAccount = false%>

<!--#include file = "MainMenu.asp"-->

<!-- start of code added TJS 24/09/21 -->	
<div style="position: relative;">
	<div id="DialogMask" style="z-index: 10; position: absolute; display:none; top: 0; left: 0; width: 1200px; height: 800px; background: rgba(0, 0, 0, 0.6)">
		<div id="AskYesNoDiv" style="position: absolute; display: none; width:420px; left: 390px; height:180px; background-color:#FFFFFF;">
			<p class="panelhdr" id="YesNoHeader"></p>
			<p id="YesNoText"></p>
			<input type="hidden" id="YesNoRes" value="">
			<p id="AskYesNoBtns" style="clear: left; padding: 10px;"><a id="YesBtn" class="continue_button">Yes</a>
				<a id="NoBtn" class="continue_button">No</a></p>
			<input type="hidden" id="NextAction" value="">
		</div>

		<div id="ConfirmDiv" style="position: absolute; display: none; width:600px; left: 300px; height:280px; background-color:#FFFFFF;">
			<p class="panelhdr" id="ConfirmHdr"></p>
			<p id="ConfirmTxt"></p>
			<input type="hidden" id="ConfAction" value="">
			<p style="text-align: center;"><a id="ConfirmBtn" class="continue_button" onclick="ConfirmClick()">OK</a></p>
		</div>
	</div>
	<!-- end of code added TJS 24/09/21 -->	

	<p>&nbsp;</p> <!-- TJS 30/05/20 -->

	<p class="panelhdr">Transfer Credit to another Employer</p>

	<%if GetSessionVar("MultiEmplerLogin") and cBool(rsUser("Employer_Admin")) and rsEmployer("Empl_Mnths_Credit") > 0 and _
		rsEmployer("Billing_Method") <> "F" and rsEmployer("Billing_Method") <> "A" then%>
		<form name="TransferCredit" method="post" action="https://<%=request.servervariables("SERVER_NAME")%>/Secure/TransferCredit.asp">
			<input type="hidden" name="ID" value="<%=SetPageSessionID(55303, DestFrame)%>">
			<input type="hidden" name="SV" value="<%=SessionVarsID%>">
			<input type="hidden" name="S" value="<%=DestFrame%>">
			<input type="hidden" name="D" value="<%=DestFrame%>">
			<input type="hidden" name="ER" value="<%=EmployerID%>">

			<p>As your login allows you access to multiple Employers, you are able to transfer Employee Payroll Months credit from the current Employer to another Employer.</p>
			<p>NOTE It is your responsibility to resolve any accounting or other issues that may arise from the transfer of credits between Employers who are different legal entities.</p>
			<p>You currently have a credit balance of <%=rsEmployer("Empl_Mnths_Credit")%> Employee Payroll Month<%if rsEmployer("Empl_Mnths_Credit") <> 1 then%>s<%end if%> and you can transfer any number of Employee Payroll Months up to this value.</p>
			<p>&nbsp;</p>
			<p><span class="spaninlineblock" style="min-width: 300px;">Number of Employee Payroll Months to transfer</span>
				<span class="spaninlineblock" style="min-width: 80px;"><input type="text" class="five-char-input<%=CheckValidationFailure("EMTransfer")%>" name="EMTransfer" id="EMTransfer" value="<%=EmplMntsToTransfer%>"></span></p>
			<p><span class="spaninlineblock" style="min-width: 120px;">Transfer credit to</span>
				<span class="spaninlineblock" style="min-width: 300px;"><select class="select-forty-char-input<%=CheckValidationFailure("TrnsER")%>" name="TrnsER" id="TrnsER">
						<option value="-1" <%if TransferToEmployerID < 0 then%>selected<%end if%>>&nbsp;</option>
						<%do while not rsTransferTo.EOF%>
							<option value="<%=rsTransferTo("Employer_ID")%>" <%if cLng(TransferToEmployerID) = rsTransferTo("Employer_ID") then%>selected<%end if%>><%=rsTransferTo("Employer_Name")%></option>
							<%rsTransferTo.movenext 
						loop%>
					</select></span></p>
		</form>

		<p><a id="TransferCredits" class="continue_button" onclick="document.TransferCredit.submit()">Transfer</a>
			<a id="Cancel" class="cancel_button" onclick="window.open('https://<%=request.servervariables("SERVER_NAME")%>/Secure/ASPDOTNET/ViewAccountHistory.aspx?ID=<%=SetPageSessionID(84214, DestFrame)%>&SV=<%=SessionVarsID%>&S=<%=DestFrame%>&D=<%=MainFrame%>&ER=<%=EmployerID%>','PayrollHome','', true);">Cancel</a> <!-- TJS 24/09/21 -->

	<%else%>
		<p>You cannot transfer credits.</p>
	<%end if%>
</div>
<%if "" & AlertMessage <> "" then
	' start of code added TJS 24/09/21
	sTemp = replace(AlertMessage, "&#x27;", "\'")
	sTemp = replace(sTemp, "\r\n\r\n", "</p><p>")
	sTemp = replace(sTemp, "\r\n", "<br>")
	sTemp = replace(sTemp, "&amp;", "&")
	iMsgLine = 1
	iPosn = instr(sTemp, "</p><p>")
	do while iPosn > 0
		iMsgLine = iMsgLine + 2
		iPosn = instr(iPosn + 1, sTemp, "</p><p>")
	loop
	iPosn = instr(sTemp, "<br>")
	do while iPosn > 0
		iMsgLine = iMsgLine + 1
		iPosn = instr(iPosn + 1, sTemp, "<br>")
	loop
	' end of code added TJS 24/09/21%>
	<script>
		DisplayAlertMsg('Transfer Credits', '<%=sTemp%>', <%=((iMsgLine * 17) +100)%>, 620); // TJS 30/10/14 TJS 24/09/21
	</script>
<%end if%>

</body>
<%rsUser.close
rsTransferTo.close
rsEmployer.close
set rsUser = nothing
set rsTransferTo = nothing
set rsEmployer = nothing

SaveSessionVarsRecord SessionVarsID ' TJS 19/06/07

ReleaseASPEncrypt ' TJS 05/10/14

objConn.close
set objConn = nothing
%>